Programming MMC1

MMC1 was Nintendo’s first ASIC mapper for the NES.

If you are using the SGROM or SNROM board to provide an environment similar to UNROM, with 8 KB of CHR RAM, a fixed PRG ROM bank at $C000, and a 16 KB switchable PRG ROM bank at $8000, do this in your init code after the mapper has been reset:

  lda #$0E   ; vertical mirroring, fixed $C000, 8 KB CHR pages
  sta $8000  ; (use $0F instead for horizontal mirroring)
  lsr a
  sta $8000
  lsr a
  sta $8000
  lsr a
  sta $8000
  lsr a
  sta $8000

Games that use CHR RAM switch to another PRG bank before they copy tile data into CHR RAM.

Some revisions of the MMC1 IC might power up in a mode other than fixed-$C000, requiring that the vectors and the start of the init code be placed in all banks, much as in BxROM or AxROM or GxROM. Other revisions guarantee that the fixed bank is loaded at power on. To make sure your code works on all MMC1 revisions, put the following code in the last 16 bytes of each 16384 byte bank. (Barbie uses almost identical code.)

reset_stub:
  sei
  ldx #$FF
  txs        ; set the stack pointer
  stx $8000  ; reset the mapper
  jmp reset  ; must be in $C000-$FFED
  .addr nmiHandler, reset_stub, irqHandler

Then to switch PRG ROM banks, load the bank number (0-15) into A and call this subroutine:

mmc1_load_prg_bank:
  sta $E000
  lsr a
  sta $E000
  lsr a
  sta $E000
  lsr a
  sta $E000
  lsr a
  sta $E000
  rts

If an NMI or IRQ can interrupt a series of writes, it is not easy to know what state the serial register was in before the interruption.

One technique for coping with this problem involves using a flag variable to indicate that a serial write should be retried^[1]:

1. The normal serial write routine should have an “interrupted” flag:
   • Clear the flag before beginning the series of writes.
   • When completed, check the flag. If an interrupt is indicated, reset the serial register, clear the interrupted flag and begin the serial writes again.
2. If the NMI or IRQ needs to switch banks, it should reset the serial register and set the “interrupted” flag to indicate that it has done this.

Another technique involves saving the bank number and resetting the mapper before every bankswitch to guarantee the correct bank is switched in after an interrupt. However, this forces the mode to be fixed-$C000^[2]:

1. The normal serial write routine should save the current bank number and reset the mapper before writing to the shift register.
2. The interrupt handler should do one of the following:
   • A. Save the current bank number on entry. Restore the current bank number, bankswitch, then reset the mapper before exiting.
   • B. If interrupts are guaranteed to never be nested, it can bankswitch without saving the bank number (but still resetting the mapper). Load the current bank number and bankswitch before exiting.

• MMC1 technical reference

1. ↑ forum post: thefox describes MMC1 interrupt technique used in STREEMERZ
2. ↑ forum post: foobles’ thread-safe MMC1 bankswap without checks

• SNROM project template by Damian Yerrick on GitHub

Edit this page on GitHub